include  tios.h
      include  genlib.h

      xdef  _main
      xdef  _comment
      xdef  _ti89

_main:
        lea.l  8+dscreen(pc),a3
        jsr    genlib::init
  
        ;|=========================================
        ;|  Init first Dscreen
        ;|=========================================
        jsr      genlib::init_dscreen      ;init dscreen 1
        jsr      genlib::push_hd            ;save handle
        move.l  a0,-(a3)                  ;save *dscreen
        move.l  a0,d0
        jsr      genlib::set_dscreen_function
        jsr      genlib::cls                ;clear dscreen1

        ;|=========================================
        ;|  Init second Dscreen
        ;|=========================================
        jsr      genlib::init_dscreen      ;init dscreen 2
        jsr      genlib::push_hd            ;save handle
        move.l  a0,-(a3)                  ;save *dscreen
        move.l  a0,d0
        jsr      genlib::set_dscreen_function
        jsr      genlib::cls    ;clear dscreen

        ;|=========================================
        ;|  Init some data
        ;|=========================================
        lea.l    helene(pc),a0              ;*sprite
        moveq    #0,d0                      ;x
        moveq    #1,d1                      ;y
        moveq    #1,d2                      ;speed of the sprite
        moveq    #0,d4                      ;temp offset for double buffering

        ;|=========================================
        ;|  Main loop
        ;|=========================================
MainLoop:
        add.w    d2,d0
        jsr      genlib::cls
        jsr      genlib::put_big_sprite

        ;|=================================
        ;|  Test the sprite position
        ;|=================================

        tst.w    d0
        bne      \NotLeft
        moveq    #1,d2
\NotLeft:
        cmpi.w  #70,d0
        bne      \NotRight
        moveq    #-1,d2
\NotRight:

        ;|=================================
        ;|  Wait
        ;|=================================
\Ready:  tst.l    genlib::timer
        beq      \Ready

        ;|=================================
        ;|  Swap the buffers
        ;|=================================
        move.w  d0,d3                      ;save x
        move.l  0(a3,d4.l),d0
        jsr      genlib::set_dscreen_int
        eori.b  #4,d4
        move.l  0(a3,d4.l),d0
        jsr      genlib::set_dscreen_function
        move.w  d3,d0                      ;restore x

        ;|=================================
        ;|  Wait
        ;|=================================
\Wait:
        tst.w    genlib::frame_timer
        beq      \Wait
        clr.w    genlib::frame_timer

        ;|=================================
        ;|  Test ESC
        ;|=================================
        movem.l  d0-d2/a0-a1,-(sp)
        jsr      tios::GKeyFlush
        movem.l  (sp)+,d0-d2/a0-a1
        move.w  GETKEY_CODE,d3
        cmpi.w  #264,d3    ;ESC
        bne      MainLoop

      ;|=========================================
      ;|  Quit
      ;|=========================================
        jsr      genlib::free_hd
        jsr      genlib::quit
        rts

;|=========================================
;|  Variables
;|=========================================
      even
dscreen:    dc.l  0,0
_comment:    dc.b  "Ma chérie! ;)",0